Managing OnBegin Execution Order

Module — 3 files

These files compile together (same module folder).

file_1.verse

using { /Fortnite.com/Devices }

awaitable_creative_device<public> := class(creative_device):

    ReadyEvent<private> : event() = event(){}
    var IsReady<private> : logic = false

    OnBegin<override>()<suspends>:void=
        defer:
            Ready()

        OnAwaitableBegin()

    OnAwaitableBegin<public>()<suspends>:void=
        block{}

    Ready<protected>():void=
        set IsReady = true
        ReadyEvent.Signal()

    AwaitBegin<public>()<suspends>:void=
        if (not IsReady?):
            ReadyEvent.Await()

vehicle_manager_device.verse

using { /Fortnite.com/Devices }
using { /Verse.org/Simulation }

vehicle_manager_device := class(awaitable_creative_device):

    @editable
    DirtbikeSpawners<private> : []vehicle_spawner_dirtbike_device = array{}

    @editable
    SportbikeSpawners<private> : []vehicle_spawner_sportbike_device = array{}

    # vehicle_spawner_device cannot be an @editable
    var VehicleSpawners<private> : []vehicle_spawner_device = array{}

    OnAwaitableBegin<override>()<suspends>:void=
        set VehicleSpawners += DirtbikeSpawners
        set VehicleSpawners += SportbikeSpawners

        Print("Vehicle manager is ready.")

    GetVehicleSpawners<public>()<transacts>:[]vehicle_spawner_device=
        return VehicleSpawners

    GetVehicleSpawner<public>(Index : int)<transacts><decides>:vehicle_spawner_device=
        return VehicleSpawners[Index]

hud_manager_device.verse

using { /Fortnite.com/Devices }
using { /Verse.org/Simulation }

hud_manager_device := class(creative_device):

    @editable
    VehicleManager<private> : vehicle_manager_device = vehicle_manager_device{}

    OnBegin<override>()<suspends>:void=
        VehicleManager.AwaitBegin()

        for (VehicleSpawner : VehicleManager.GetVehicleSpawners()):
            VehicleSpawner.AgentEntersVehicleEvent.Subscribe(OnAgentEntersVehicle)
            VehicleSpawner.AgentExitsVehicleEvent.Subscribe(OnAgentExitsVehicle)

        Print("HUD manager is ready.")

    # show/hide some HUD widgets
    OnAgentEntersVehicle(Agent : agent):void=
        block{}

    # show/hide some HUD widgets
    OnAgentExitsVehicle(Agent : agent):void=
        block{}

Copy-paste each file above is always free.

Managing OnBegin Execution Order

Comments