Automatic Sliding Door

Module — 2 files

These files compile together (same module folder).

file_1.verse

Start by creating a new verse device named automatic_sliding_door_device and open it is Visual Studio Code, copy and paste the provided verse code and save. Back within UEFN, Ctrl+Shift+B to build verse code. 

Place down a Capture_Area_Device so that it overlaps with your door frame, and set the following options in the details panel:
Capture Radius 0.5 (this value is the overlap size that triggers our door)
Untick Visible During Game
Untick Item Visible in Game
Untick Consume Item on Scoring
Untick Consume Item On Scoring
Untick Display control VFX
Untick Display ownership change VFX
Untick Play Sounds Alerts
Untick Show Objective pulse (all 3 of them)
Clear the HUD Message

All of these options basically make the capture zone inert (it doesn't do anything) but it does still have overlap events that we will bind our code to.

Next, pick a suitable door prop from the available fortnite assets, and drag it into your level. In the details panel, untick Register with Structural Grid.

You will also need to drag in a Switch_Device.
Finally, place your automatic_sliding_door_device within your level, location of this device is irrelevant. In the details panel, select your door prop as the door Prop, you can either use the drop-down list, or use the eyedropper (and then just click on your door in the view-port). Do the same to select your capture area, and switch devices. Save all and launch a session, your door should now slide to the right when any player is within your capture zone area. If the door moves in the wrong direction, please take a look at the comments within the below verse code.

automatic_sliding_door_device.verse

using { /Fortnite.com/Devices }
using { /Verse.org/Simulation }
using { /UnrealEngine.com/Temporary/SpatialMath }
using { /UnrealEngine.com/Temporary/Diagnostics }


# A Verse-authored creative device that controls a sliding door or gate prop based on players being in proximity (triggered by the otherwise inert capture zone)
automatic_sliding_door_device := class(creative_device):
    @editable
    DoorProp:creative_prop=creative_prop{}

    @editable
    DoorTriggerVolume:capture_area_device=capture_area_device{}

    @editable
    ReplicationSwitch:switch_device=switch_device{}
    
    #Fortnite grid size is 512x512x384
    #Set this value to negative to change the direction of opening
    HorizontalGridSize:float=512.0
    var ClosedTranslation:vector3=vector3{X:=0.0, Y:=0.0, Z:=0.0}

    # Runs when the device is started in a running game
    OnBegin<override>()<suspends>:void=
        #Bind First and Last Agent events to control the switch
        DoorTriggerVolume.FirstAgentEntersEvent.Subscribe(OnAgentEntered)
        DoorTriggerVolume.LastAgentExitsEvent.Subscribe(OnAgentExited)

        #bind the switch state changes to control the door movement
        #using this 2 step process should ensure that the door will open and close for all players. This might be completely redundant, I have no way of testing that at this time
        ReplicationSwitch.TurnedOnEvent.Subscribe(OnDoorOpen)
        ReplicationSwitch.TurnedOffEvent.Subscribe(OnDoorClose)


    OnAgentEntered(Agent:agent):void=
        #Print("Agent Entered")
        ReplicationSwitch.TurnOn(Agent)
    OnAgentExited(Agent:agent):void=
        #Print("Agent Exited")
        ReplicationSwitch.TurnOff(Agent)
    
    OnDoorOpen(Agent:agent):void=
        #Print("Door Opened Called")
        if (ClosedTransform:=creative_object[DoorProp].GetTransform()):
            #First we get and save the original location of the door
            set ClosedTranslation = ClosedTransform.Translation
            
            #Depending on the mesh, you might need to use the localForward() or the LocalRight(), 
            #DoorRightVector:vector3=ClosedTransform.Rotation.GetLocalRight()
            DoorRightVector:vector3=ClosedTransform.Rotation.GetLocalForward()

            #you can change the open direction via (DoorRightVector*HorizontalGridSize*-1.0) (or set the HorizontalGridSize to -512.0)
            OpenedTranslation:vector3=(DoorRightVector*HorizontalGridSize)+ClosedTranslation

            
            #This teleport command has to be wrapped inside of an if statement
            if(DoorProp.TeleportTo[OpenedTranslation,ClosedTransform.Rotation]):
                Print("Door has been Opened")

    OnDoorClose(Agent:agent):void=
        Print("Door Closed")
        #get the transform so we can use the rotation
        if (OpenedTransform:=creative_object[DoorProp].GetTransform()):
            #teleport the door back into the closed position
            if(DoorProp.TeleportTo[ClosedTranslation,OpenedTransform.Rotation]):
                Print("Door has been Closed")

Copy-paste each file above is always free.

Automatic Sliding Door

Comments